Adobe ColdFusion 8

cfloop: index loop

Description

An index loop repeats for a number of times that is determined by a numeric value. An index loop is also known as a FOR loop.

Syntax

<cfloop 
    index = "parameter name"
    from = "beginning value"
    to = "ending value"
    step = "increment">
        HTML or CFML code ...
</cfloop>

See also

cfabort, cfbreak, cfdirectory, cfexecute, cfexit, cfif, cflocation, cfrethrow, cfswitch, cfthrow, cftry; "cfloop and cfbreak" in the ColdFusion Developer's Guide

Attributes

Attribute

Req/Opt

Default

Description

index

Required

 

Index value. ColdFusion sets it to the from value and increments or decrements by step value, until it equals the to value.

from

Required

 

Beginning value of index.

to

Required

 

Ending value of index.

step

Optional

1

Step by which to increment or decrement the index value.

Usage

Using anything other than integer values in the from and to attributes of an index loop can product unexpected results. For example, if you increment through an index loop from 1 to 2, with a step of 0.1, ColdFusion outputs "1,1.1,1.2,...,1.9", but not "2". This is a programming language problem regarding the internal representation of floating point numbers.

Note: The to value is evaluated once, when the cfloop tag is encountered. Any change to this value within the loop block, or within the expression that evaluates to this value, does not affect the number of times the loop is executed.

Example

In this example, the code loops five times, displaying the index value each time:

<cfloop index = "LoopCount" from = "1" to = "5">
    The loop index is <cfoutput>#LoopCount#</cfoutput>.<br>
</cfloop>

The output of this loop is as follows: 

The loop index is 1. 
The loop index is 2. 
The loop index is 3. 
The loop index is 4. 
The loop index is 5.

In this example, the code loops four times, displaying the index value each time. The value of j is decreased by one for each iteration. This does not affect the value of to, because it is a copy of j that is made before entering the loop.

<cfset j = 4>
<cfloop index = "LoopCount" from = "1" to = #j#>
    <cfoutput>The loop index is #LoopCount#</cfoutput>.<br>
    <cfset j = j - 1>
</cfloop>

The output of this loop is as follows: 

The loop index is 1. 
The loop index is 2. 
The loop index is 3. 
The loop index is 4.

As before, the value of j is decremented by one for each iteration, but this does not affect the value of to, because its value is a copy of j that is made before the loop is entered.

In this example, step has the default value, 1. The code decrements the index:

<cfloop index = "LoopCount" 
    from = "5" 
    to = "1" 
    step = "-1">
The loop index is <cfoutput>#LoopCount#</cfoutput>.<br>
</cfloop>

The output of this loop is as follows: 

The loop index is 5. 
The loop index is 4. 
The loop index is 3. 
The loop index is 2. 
The loop index is 1.